How to do it...

To complete this recipe, do the following:

1. Create the following table:

R03_Interpolation = 
    SELECTCOLUMNS(
        GENERATESERIES(1,373,1),
        "Temp (C)",
        [Value]
    )

2. Create the following measure in the R03_Interpolation table:

Pressure (MPa) = 
    VAR __x = MAX('R03_Interpolation'[Temp (C)])
    VAR __match = 
    LOOKUPVALUE(
        'R03_Table'[Pressure (MPa)],
        'R03_Table'[Temp (C)],__x,
        BLANK()
    )
RETURN
    IF(
        ISBLANK(__match),
            VAR __x0 = 
                MAXX(
                    FILTER('R03_Table','R03_Table'[Temp (C)]<__x),
                    'R03_Table'[Temp (C)]
                )
            VAR __x1 = 
                MINX(
                    FILTER('R03_Table','R03_Table'[Temp (C)]>__x),
                    'R03_Table'[Temp (C)]
                )
            VAR __y0 = 
                LOOKUPVALUE(
                    'R03_Table'[Pressure (MPa)],
                    'R03_Table'[Temp (C)],__x0,
                    BLANK()
                )
            VAR __y1 = 
                LOOKUPVALUE(
                    'R03_Table'[Pressure (MPa)],
                    'R03_Table'[Temp (C)],__x1,
                    BLANK()
                )
        RETURN __y0 + (__x - __x0) * (__y1 - __y0)/(__x1 - __x0),
        __match
    )

3. On a Report page, create a Scatter chart visualization and place the Temp (C) column from the R03_Table table into the X Axis field. Set Temp (C) to Don't summarize.
4. In the same visual, place the Pressure (MPa) column from the R03_Table table into the Y Axis field.
5. On the same Report page, create a second Scatter chart visualization and place the Temp (C) column from the R03_Interpolation table into the X Axis field. Set Temp (C) to Don't summarize.
6. In this second visual, place the Pressure (MPa) measure from the R03_Table table into the Y Axis field.

The first visualization demonstrates the holes in the data. The R03_Table table only contains data about certain values of Temp (C). The second visualization demonstrates the smooth curve created by the linear interpolation of values between known data points.