How to do it...

Calculating ETR can be done as follows:

1. Create the following measure:

Annual ETR = 
    VAR __Year = 2019
    VAR __StartPeriod = DATE(__Year,1,1)
    VAR __EndPeriod = DATE(__Year,12,31)
    VAR __BeginningEmployees = 
        COUNTROWS(
            FILTER(
                'R01_Table',
                'R01_Table'[Hire Date] <= __StartPeriod && 
                    'R01_Table'[Leave Date] > __StartPeriod
            )
        )
    VAR __EndingEmployees = 
        COUNTROWS(
            FILTER(
                'R01_Table',
                'R01_Table'[Hire Date] <= __EndPeriod && 
                    ('R01_Table'[Leave Date] > __EndPeriod || 
                        'R01_Table'[Leave Date] = DATE(9999,1,1)
                    )
            )
        )
    VAR __LostEmployees = 
        COUNTROWS(
            FILTER(
                'R01_Table',
                'R01_Table'[Leave Date] >= __StartPeriod &&
                'R01_Table'[Leave Date] <= __EndPeriod
            )
        )
RETURN
    DIVIDE(
        __LostEmployees,
        (__BeginningEmployees + __EndingEmployees) / 2,
        0
    )

2. Format ETR as a percentage.
3. On a report page, create a Card visualization and place the ETR measure in the Fields area of the visualization.