There's more...

Another common metric used in absenteeism is the Bradford Factor. The underlying assumption with the Bradford Factor is that frequent short unplanned absences are more disruptive than infrequent longer unplanned absences. The Bradford Factor is given by the following equation:

The Bradford Factor is intended to be computed annually and only at the individual employee level. To calculate the Bradford Factor, create the following measure:

Bradford Factor = 
    VAR __StartPeriod = MIN('R02_Calendar'[Date])
    VAR __EndPeriod = MAX('R02_Calendar'[Date])
    VAR __AbsentTable = 
        ADDCOLUMNS(
            ADDCOLUMNS(
                FILTER(
                    'R02_Absent',
                    ([AbsentStartDate] >= __StartPeriod && 
                        [AbsentReturnDate] <= __EndPeriod
                    ) ||
                        ([AbsentStartDate] < __StartPeriod && 
                            [AbsentReturnDate] > __StartPeriod && 
                                [AbsentReturnDate] <= __EndPeriod
                        ) ||
                            ([AbsentStartDate] >= __StartPeriod && 
                                [AbsentStartDate] <= __EndPeriod && 
                                    [AbsentReturnDate] > __EndPeriod
                            )
                ),
                "__AbsentStartDateInPeriod",
                    IF([AbsentStartDate]<__StartPeriod,
                        __StartPeriod,
                        [AbsentStartDate]
                    ),
                "__AbsentEndDateInPeriod",
                    IF([AbsentReturnDate]>__EndPeriod,
                        __EndPeriod,
                        [AbsentReturnDate]
                    )
            ),
            "__DaysAbsent",
            ([__AbsentEndDateInPeriod]-[__AbsentStartDateInPeriod])*1+1
        )
    VAR __TotalDaysAbsent = SUMX(__AbsentTable,[__DaysAbsent])
    VAR __Instances = COUNTROWS(__AbsentTable)
    VAR __BradfordFactor = POWER(__Instances,2) * __TotalDaysAbsent
RETURN
    IF(ISBLANK(__BradfordFactor),0,__BradfordFactor)