There's more...

We can modify these measures slightly to track revenue versus budget for the entire year. To see how this works, do the following:

1. Create the following measures:

Running Yearly Revenue = 
    VAR __Date = MAX('R07_Revenue'[Date])
    VAR __Year = YEAR(__Date)
RETURN
    SUMX(
        FILTER(
            ALL('R07_Revenue'), 
            YEAR([Date]) = __Year && 
                [Date] <= __Date
        ),
        'R07_Revenue'[Revenue]
    )

Running Yearly Budget Per Day = 
    VAR __Date = MAX('R07_Revenue'[Date])
    VAR __Month = MONTH(__Date)
    VAR __Year = YEAR(__Date)
    VAR __Day = DATEDIFF(DATE(__Year,1,1),__Date,DAY) + 1
    VAR __Budget = SUM([Budget])
    VAR __Days = DATEDIFF(DATE(__Year,1,1),DATE(__Year,12,31),DAY) + 1
RETURN
    __Budget * __Day / __Days

2. On a Report page, create a Clustered column chart visualization and place the Date column from the R07_Revenue table into the Axis area and place the Running Yearly Revenue and Running Yearly Budget Per Day measures in the Value area. 

The only change we've made to the Running Yearly Revenue measure with respect to the Running Monthly Revenue measure is that we remove any references to the month. For the Running Yearly Budget Per Day measure, the differences lie in how we calculate the current day of the year, __Day, and the total days in the year, __Days, using DATEDIFF.

We can also use our measure calculations to return a percentage that indicates how much our running revenue is above or below our running budget per day. To see how this works, do the following:

1. Create the following measure:

Percent of Budget = [Running Monthly Revenue] / [Running Monthly Budget Per Day]

2. On a Report page, create a Line chart visualization and place the Date column from the R07_Revenue table into the Axis area. Then, place the Percent of Budget measure into the Value area.