How to do it...

To implement this recipe, do the following:

1. Create the following measures:

Availability = 
    VAR __Table = 'R04_Availability'
    VAR __Table1 = 
        ADDCOLUMNS(
            ADDCOLUMNS(
                __Table,
                "__Next",
                MINX(
                    FILTER(
                        __Table,
                        [MachineName] = EARLIER([MachineName]) && 
                        [RepairStarted] > EARLIER([RepairStarted])    
                    ),
                    [RepairStarted]
                )
            ),
            "__Uptime",
            IF(ISBLANK([__Next]),
                DATEDIFF([RepairCompleted],DATE(2013,12,31),SECOND),
                DATEDIFF([RepairCompleted],[__Next],SECOND)
            )
        )        
    VAR __TotalUptime = SUMX(__Table1,[__Uptime])
    VAR __Days = 
        DATEDIFF(
            DATE(2010,1,1),
            DATE(2013,12,31),
            DAY) + 1
    VAR __MaxAvailable = 24 * 60 * 60 * __Days
RETURN
    DIVIDE(__TotalUptime, __MaxAvailable)

Performance = 
    DIVIDE(
        SUMX('R04_Production','R04_Production'[Actual]),
        SUMX('R04_Production','R04_Production'[Capacity]),
        0
    )

Quality = 
    DIVIDE(
        SUMX('R04_Production','R04_Production'[Good]),
        SUMX('R04_Production','R04_Production'[Actual]),
        0
    )

OEE = [Availability] * [Performance] * [Quality]

2. On a Report page, create a table visualization and place the MachineName column from the R04_Machines table into the Values area along with the Availability, Performance, Quality, and OEE. measures.