The logistics application

Shipment - OnAfterGetRecord()

IF Route.Description <> Warehouse.Name THEN BEGIN
  Route."No." := '';
  Route.Description := Warehouse.Name;
  Route."Shipment Date" := WORKDATE;
  Route.Status := Route.Status::Planned;
  
  Route."Bill-to Customer No." := "Bill-to Customer No.";
  Route."Bill-to Name" := "Bill-to Name";

  Route.INSERT(TRUE);
  i := 0;
END;

i := i + 10000;

RouteStop."Route No." := Route."No.";
RouteStop."Line No." := i;
RouteStop.Type := RouteStop.Type::Pickup;
RouteStop.VALIDATE("Shipment No.", "No.");
RouteStop.INSERT;

i := i + 10000;

RouteStop."Route No." := Route."No.";
RouteStop."Line No." := i;
RouteStop.Type := RouteStop.Type::Delivery;
RouteStop.VALIDATE("Shipment No.", "No.");
RouteStop.INSERT;

After the routes are created and the shipments are assigned to a stop, a grouping and optimizing algorithm is started. This is codeunit Route Optimizer (123456700).

Route optimizer

The algorithm in our example is designed to find the optimal route to deliver the products to the addresses by calculating the distance of each address from the warehouse. The route starts from the address that is closest to our warehouse and ends at the address that is the farthest away.

This is just an example of a simple algorithm. Each company will have its own algorithm that needs to be implemented:

RouteStopPickup.SETRANGE("Route No.", Route."No.");
RouteStopPickup.SETRANGE(Type, RouteStopPickup.Type::Pickup);
RouteStopPickup.FINDFIRST;

RouteStopDelivery.SETRANGE("Route No.", Route."No.");
RouteStopDelivery.SETRANGE(Type, RouteStopDelivery.Type::Delivery);
RouteStopDelivery.FINDSET;
REPEAT
  Window.UPDATE(2, RouteStopDelivery."Shipment No.");

  IF NOT Optimizer.GET(RouteStopDelivery.Name) THEN BEGIN
    CLEAR(BingMapMgt);
    BingMapMgt.CalculateRoute('', RouteStopPickup.Latitude, RouteStopPickup.Longitude,'', RouteStopDelivery.Latitude,
      RouteStopDelivery.Longitude, Optimizer."Distance (Distance)",Optimizer."Activity Time", Optimize::Distance);

    Optimizer.Name := RouteStopDelivery.Name;
    Optimizer.Latitude := RouteStopDelivery.Latitude;
    Optimizer.Longitude := RouteStopDelivery.Longitude;
    Optimizer.INSERT;
  END;
  
UNTIL RouteStopDelivery.NEXT = 0;

The calculation of the distance is done by calling a web service from Bing Maps. This is explained in Chapter 9, Interfacing.

Each distance is stored as a record into the Optimizer table, which is a helper table. This table is a temporary variable in this codeunit.

Temporary tables have multiple benefits that make them interesting to use. As they are not stored in the database, they have much better performance compared to real tables. This also has a benefit for concurrency since there can be no locking.

Tip

Temporary tables are free to use. They are not checked in the license file when used. To create and modify the definition, a valid license is still required. The video at https://www.youtube.com/watch?v=QHn5oEOJv0Q shows how to use temporary datasets.

After generating the distances, all Pickup shipments are combined into one stop by assigning them all to the same Sequence No. value:

RouteStopGroup.INIT;
RouteStopGroup."Route No." := Route."No.";
RouteStopGroup."Line No." := 10;
RouteStopGroup.Type := RouteStopGroup.Type::"Pickup Group";
RouteStopGroup."Sequence No." := 10;
RouteStopGroup.Name := RouteStopPickup.Name;
RouteStopGroup.INSERT;

RouteStopPickup.MODIFYALL("Sequence No.", 10);

By sorting the distance helper table on distance, we can easily assign the correct Sequence No. to the delivery stops. For each Sequence No. value, we will also generate a group record in the stop table:

Optimizer.SETCURRENTKEY("Distance (Distance)");
Optimizer.ASCENDING(FALSE);
Optimizer.FIND('-');
REPEAT
  RouteStopGroup.INIT;
  RouteStopGroup."Route No." := Route."No.";
  RouteStopGroup."Line No." := Sequence;
  RouteStopGroup.Type := 
    RouteStopGroup.Type::"Delivery Group";
  RouteStopGroup."Sequence No." := Sequence;
  RouteStopGroup.Name := Optimizer.Name;
  RouteStopGroup.INSERT;

  RouteStopDelivery.SETRANGE(Name, Optimizer.Name);
  RouteStopDelivery.MODIFYALL("Sequence No.", Sequence);
  
  Sequence := Sequence + 10;
  IF (xLongitude <> Optimizer.Longitude) OR 
    (xLatitude <> Optimizer.Latitude) 
  THEN BEGIN
    IF xLongitude + xLatitude <> 0 THEN BEGIN
      CLEAR(BingMapMgt);
      BingMapMgt.CalculateRoute('', xLatitude, xLongitude,'', 
        Optimizer.Latitude, Optimizer.Longitude, 
        RouteStopGroup.Distance, RouteStopGroup.Time, 
        Optimize::Distance);
      RouteStopGroup.MODIFY;
    END;
    xLongitude := Optimizer.Longitude;
    xLatitude := Optimizer.Latitude;
  END;
UNTIL Optimizer.NEXT = 0;

After optimizing the route, it should look something like what is shown in the following screenshot. We pick up two shipments at the warehouse and drive them to two addresses in the country.

Route follow up

During the route, the planner needs to follow up with the driver. This will result in the status update of the shipment.

In our solution, the planner should populate the Date Time Completed field. This field is automatically updated in the shipment using a flow field.

Incidents

A special status for a shipment is an incident. If, for any reason, we cannot deliver the shipment, it should be taken back to the warehouse and shipped again. Based on the reason of the incident, we might need to invoice extra services.

The incident can be on a stop group or on an individual shipment and can have status Undeliverable, Closed, or Other. The planner can add extra comments.

The other shipments that do not have incidents get the new status, while the incidents move to another place on the Role Center.

Follow up

The incidents can be followed up by the planner via the Role Center. Incidents that have not been handled, keep the status open until someone decides what to do with it.